Klasse E Versterkers

In de vorige hoofdstukken hebben we de C en F versterkers besproken. Dit zijn hoogfrequent versterkers met 1 vermogen transistor in de vermogentrap.

In dit hoofdstuk bestuderen we de klasse E versterker. Ook Klasse E versterkers zijn resonante versterkers die bestaan uit een LRC trilkring (of meerdere LC kringen) die aangestuurd wordt door een enkele transistor. Als een gevolg hiervan werkt deze versterker op een vaste frequentie of binnen een zeer beperkte bandbreedte rond deze centrale frequentie. Deze bandbreedte is typisch maximaal 1\( \% \) van de resonantie frequentie. In Tabel 4 geven we een overzicht van deze verschillende versterkers.

Tabel 4 Indeling van de vermogenversterkers

	laagfrequent of breedband	hoogfrequent of resonant
1 transistor in de vermogentrap	Klasse A	Klasse C Klasse F Klasse E
2 of meer transistors in de vermogentrap	Klasse B Klasse G	Klasse D

Fig. 66 toont het basisschema van de klasse E versterker. Hierin herkennen we een serie resonante kring (\(C_2 L_2\)) die de belasting \(R_L\) aanstuurt. Het spoel \(L_1\) voorziet dat de stroom van de voeding \(V_{DD}\) naar de ingang van de seriekring redelijk constant wordt gehouden terwijl de spanning aan deze ingang kan varieren. De condensator \(C_1\) voorziet een AC stroompad naar de grond in het geval dat de transistor niet in geleiding is.

Fig. 66 Basisschema van de Klasse E versterker.

Voor de praktisch implementatie mag de volgorde van C₂ en L₂ omwisseld worden. Dit heeft geen enkele invloed op de werking van de seriekring.

De klasse E versterker is een zeer efficiënte hoogfrequent versterker die gebruik maakt van:

• Eén enkele vermogentransistor als schakelend element

• Resonante LRC trilkring voor frequentieselectie

• Optimale timing tussen spanning en stroom voor minimaal vermogenverlies

• Hoge efficiëntie (tot 95% theoretisch mogelijk)

De klasse E versterkers zijn initieel uitgewerkt door Sokal and Sokal [3], [4] ,[5] vanuit de basisredenering dat we dat we op elk moment het gedisipeerde vermogen in de transistor zo laag mogelijk moeten houden. Dit kan door veel stroom door de transistor moeten laten lopen wanneer de spanning minimaal is en dat we geen stroom door de transistor laten lopen als de spanning over de transistor hoog is. Deze afwisseling tussen stroom en spanning vereist een hele goede timing:

• Wanneer we op het juiste moment de transistor uit geleiding brengen, gaat de spanning over de transistor variëren terwijl er geen stroom loopt. De spanning over de transitor is op het moment van het uit geleiding brengen 0 en de trilkring zorgt ervoor de spanning over de transistor na een bepaalde tijd terug 0 gaat worden, waarna we de transistor terug in geleiding kunnen brengen.

• Wanneer de transistor in geleiding is, kan er veel stroom lopen door de transistor, maar de transistor kan ook de spanning tussen source en drain (of tussen emitter en collector) zeer laag houden.

In beide tijdsintervallen is er dus weinig of geen vermogenverbruik. Om dit te bekomen is een goede timing van het inschakelmoment en het uitschakelmoment cruciaal.

Verklaring van de werking stap voor stap

In deze sectie verklaren we de werking van de Klasse E versterking door stap voor stap het schema op te bouwen en hierbij telkens de stromen en de spanningen te bespreken als functie van de tijd. We beginnen hierbij met de serie resonante kring, zoals aangegeven in Fig. 67. Wanneer we aan de ingang van de seriekring (aangegeven door de rode knoop) een signaal aanleggen, zal er een sinusvormige stroom lopen door de seriekring en dus ook door de belasting \(R_L\). Als een gevolg hiervan krijgen we een sinusvormige spanning en stroom door de belasting.

Fig. 67 Resonante seriekring van de klasse E versterker.

Het verloop van deze stroom als functie van de tijd is weergegeven in Fig. 68. De gemiddelde waarde van deze stroom is 0 mA.

Fig. 68 Stroomverloop in de resonante seriekring van de klasse E versterker.

Vervolgens voegen we een spoel (\(L_1\)) toe tussen de voeding en de ingangsknoop van de seriekring (zie Fig. 69). Deze spoel zal zorgen voor een zo constant mogelijke stroom bovenop de sinusvormige stroom in Fig. 68.

Fig. 69 Voeding van de resonante seriekring met een DC stroom aan de hand van het spoel L1 van de klasse E versterker.

In Fig. 70 toont het verloop van de som van beide stromen die naar de rode knoop lopen. We zien dat we in dit geval een DC componente van 400 mA bovenop de sinuscomponente komt.

Fig. 70 Voeding van de resonante seriekring met een DC stroom aan de hand van het spoel L1 van de klasse E versterker.

Natuurlijk moet op basis van de stroomwet van Kirchhoff de netto stroom naar elke knoop 0 zijn.

(9)\[\begin{equation}\label{eq:Kirchoff} \sum_{j \neq i}^n I_{ij}=0. \end{equation}\]

Wanneer dit niet zo zou zijn zou de spanning op deze knoop snel gaan stijgen of dalen tot dat wel het geval wordt. De snelheid waarmee dat gebeurt hangt af van de (parasitaire) capaciteit van de knoop.

In de plaats van te werken met een ongekende parasitaire capaciteit, kunnen we beter een goed gekozen condenstor \(C_1\) plaatsen, zoals aangegeven in Fig. 71. De nettostroom naar de rode knoop zal dan nu lopen naar deze condenstor waardoor aan de wetten van Kirchhoff voldaan is.

De spanning op de rode knoop is dan vervolgens bepaald door de lading op de condensator \(C_1\). Deze lading wordt bekomen door de integratie van de stroom op de condensator \(C_1\):

\[v=\frac{1}{C_1}\int_0^t i(t) dt \]

Fig. 71 Integratie van de stroom op de condensator C1.

In Fig. 72 tonen we het verloop van de spanning op de rode knoop die we zouden bekomen door integratie van de stoom (die getoond werd in Fig. 70) op een condensator van 4.7nF.

Fig. 72 Integratie van de stroom op de condensator C1.

In het schema van Fig. 72 zien we dat de spanning over de condensator \(C_1\) continu gaat blijven stijgen. Dit is natuurlijk niet gewenst omdat we dan geen periodiek signaal krijgen en omdat dat een veel te hoge voedingsspanning zou vereisen. We moeten er echter wel mee rekening houden dat de integratie op \(C_1\) slechts begint vanaf het moment wanneer er stroom vloeit naar \(C_1\).

Fig. 73 Integratie van de stroom op de condensator C1.

We kunnen het startpunt van de integratie van de stroom bepalen door het moment te bepalen vanaf wanneer er stoom loopt naar de condensator \(C_1\). Door deze startmomenten goed te kiezen, kunnen we telkens momenten kiezen dat de spanning later terug 0 wordt, wat dan het stopmoment wordt. Deze keuze van deze start en stopmomenten is aangegeven in Fig. 73.

In een volgende stap voegen we een transistor toe om de spanning over de condensator \(C_1\) op 0V te houden gedurende een bepaalde tijd zodat we, als de oscillatie daarna verder loopt we op een gegeven moment in tijd kunnen terugkeren naar de huidige spanning. Dat geeft ons dan het schema zoals aangegeven in Fig. 74.

Fig. 74 Transistor om de spanning op 0 te houden.

Het resultaat van de simulatie met dit schema zien we in Fig. 75.

Fig. 75 Spanningsverloop na integratie van de stroom op de condensator C1.

Uitbreiding van het schema met een derde harmonische filter

In 2013 werd het originele design uitgebreid door ook de derde harmonische weg te filteren [6]. In dit schema (zie ) voegen we een parallelkring voor de derde harmonische frequentie (\(L_3 C_3\)) toe aan de seriekring voor de eerste harmonische (\(L_2 C_2\)). Op deze manier combineren we de voordelen van klasse E en klasse F versterkers.

Fig. 76 Klasse E met derde harmonische filter

Uitgewerkte voorbeelden

Hieronder lichten we de praktische uitwerking van de klasse E versterker toe aan de hand van 3 uitgewerkte voorbeelden:

• Een 5W versterker bij 475 kHz

• Een 50W versterker bij 137.77 kHz

• Een 1W on chip versterker bij 2 GHz voor GSM toepassingen

Ontwerpvergelijkingen voor laagfrequent Klasse E Versterkers

Voor het ontwerpen van een aantal voorbeelden kunnen we de ontwerpvergelijkingen gebruiken vanuit [5]. Deze ontwerpvergelijkingen zijn uitgewerkt voor lagere frequenties. Voor MHz frequenties (en hoger) moet er in detail geanalyseerd en gesimuleerd worden. De onderstaande vergelijkingen (Eq.(10) tot Eq.(13)) kunnen daarvoor niet gebruikt worden.

Voor frequenties beneden 1 MHz:

(10)\[R_L= 0.5768 \frac{(V_{DD}-V_{sat})^2}{P} \left(1.00001-\frac{0.4144}{Q}-\frac{0.5775}{Q^2}+\frac{0.206}{Q^3} \right) \]

(11)\[C_1= \frac{1 }{5.4466 \omega R_L} \left(0.99866+\frac{0.91424}{Q}-\frac{1.03175}{Q^2}\right)+\frac{0.6}{\omega^2 L_1} \]

(12)\[C_2= \frac{1 }{\omega R_L} \left( \frac{1 }{Q-0.104823} \right)\left(1.00121+\frac{1.01468 }{Q-1.7879} \right)-\frac{0.2}{\omega^2 L_1} \]

(13)\[L_2=\frac{Q R_L}{\omega} \]

met \(\omega=2 \pi f\), \(f\) de frequentie, \(P\) het gewenste vermogen, \(V_{sat}\) de saturatiespanning van de transistor en \(Q\) de vereiste kwaliteitsfactor van de kring. De namen van de componenten komen overeen met het schema . De bovenstaande vergelijkingen (Eq.(10) tot Eq.(13)) laten ons dus toe om het schema op te stellen op basis van \(P\), \(V_{DD}\), \(f\) en \(Q\). Enkel \(L_1\) kan hierbij vrij gekozen worden. Dit moet wel gedaan worden op een zodanige wijze dat realistische waardes voor alle andere componenten bekomen worden. In veel praktische gevallen zal de impedantie van de belasting (\(R_L\)) al vast liggen, bijvoorbeeld wanneer een specifieke antenne moet gebruikt worden. In dat geval moeten we de vergelijking Eq.(10) omkeren en de voedingsspanning (\(V_{DD}\)) met \(R_L\) als gegeven. Ook komt vaak voor dat de kwaliteitsfactor \(Q\) niet gegeven is. In dit geval is het theoretisch te verkiezen om \(Q\) zo hoog mogelijk te kiezen, we zien onmiddellijk uit Eq.(13) dat dat dan een te hoge waarde voor \(L_2\) zou geven.

Voorbeeld 1: 5W versterker bij 475 kHz

We ontwerpen een klasse E versterker die een vermogen van 5W moet kunnen leveren bij een frequentie van 475 kHz, bij een voedingsspanning van 12.5V, met een Q factor van 5 en een saturatiespanning van de bipolaire transistor van 0.5 V. Wanneer we de vergelijkingen Eq.(10) tot Eq.(13) gebruiken om de elementen van dit circuit uit te rekenen bekomen we de volgende waardes voor de verschillende componenten:

RL = 14.88 Ohm
C₁ = 4.78 nF (i.e. complexe impedantie van -70.07 i Ohm)
C₂ = 6.04 nF (i.e. complexe impedantie van -55.50 i Ohm)
L₂ = 24.93 uH (i.e. complexe impedantie van 74.39 i Ohm)
Totale complexe impedantie (seriekring):  18.89 i Ohm
Maximale stroom uit de voeding: 416.67 mA
Maximale source-drain spanning (transistor): 55.62 V
Hierbij werd een 80% veiligheidsmarge genomen
We kunnen de uitgang omwerken naar een impedantie van 50 Ohm
door een transformator met wikkelverhouding: 1.83 

Het bekomen schema met de waardes van alle componenten aangegeven vinden we terug in Fig. 77.

Fig. 77 Uitgewerkt schema van het eerste voorbeeld

De overeenkomende spice file vinden we onder Spice Listing 12 en het resulaat van het opstarten van de versterken kunnen we terugvinden onder Fig. 78.

Spice Listing 12 Klasse E spice file

* Class E amp 1
M_M1         2 1 0 0 FDB33N25 
L_L1         2 3  1000uH  
C_C1         2 0  4.78nF  
L_L2         4 5  24.93uH  
C_C2         2 4  6.04nF  
R_RL         5 0  14.88 
V_Vdd        3 0 12.5V
V_Vin        1 0 PULSE(0 9 1.05u 20n 20n 1.05u 2.10526u) DC=0
.model FDB33N25 VDMOS(Rg=3 Rd=40m Rs=27m Vto=5.35 Kp=35 lambda=.05 Cgdmax=1.1n Cgdmin=25p Cgs=1.7n Cjo=800p Is=7.94p Rb=7m mfg=Fairchild Vds=250 Ron=94m Qg=37n)

Fig. 78 Verloop van de spanningen bij het opstarten van de oscillatie.

Het is interessant van de opstartsequentie in detail te bekijken. We zien in Fig. 79 dat zeker in het begin van de opstart de spanning over de transistor \(V_{SD}\), dit is de spanning op knoop 2, niet helemaal naar 0 terugkeert voor de stoom begint te lopen. Dit geeft al aan dat, ondanks de poging om dit ontwerp perfect te krijgen, er zeker nog ruimte is voor verbetering. we merken ook dat de spanning over de elementen van de trilkring veel hogere waardes bekomen dan de spanning aan de uitgang. Hiervoor vergelijk je best de spanning op knoop 4 met de spanning op knoop 5.

Fig. 79 Initieel verloop van de spanningen bij het opstarten van de oscillatie.

De Fig. 79 toont enkel de spanningen. Om een goed zicht op de efficientie te bekomen moeten we zowel naar de spanning over de transistor als de stroom door de transistor kijken. Aan de linkerkant op Fig. 80 zijn beide zichtbaar. We verwachten dat we nooit gelijktijdig stroom door en spanning over de transistor hebben. We zien dat dat toch heel kort het geval is.

Het product van de stroom door en spanning over de transistor levert ons het momentaan vermogenverbruik (en dus de opwarming) van de transistor. Dit vinden we in de blauwe lijn (\(P(M1)\)) rechtsboven op Fig. 80 terug. We moeten dit vergelijken met het totale vermogen dat door de voeding (\(P(V_{DD})\)) geleverd (orange lijn) wordt. Geintegreerd over de tijd, zien we dat het energieverbruik in de transistor veel lager is dan het totale energieverbruik. Rechtsonder op Fig. 80 tonen we de stroom door de transistor ten opzichte van de spanning over de transistor. Het verloop blijft kort bij de assen van de grafiek, waardoor het vermogenverlies beperkt blijft. Op diezelfde figuur kan je ook het verloop van de stroom door de voeding ten opzichte van de voedingsgspanning zien (orange puntje). Aangezien beiden nauwelijks veranderen is dit verloop bijna niet zichtbaar.

Fig. 80 (links) Spanningen over (boven) en stromen door (onder) de transistor en de voeding als functie van de tijd voor 1 periode van de oscillatie. (rechts boven) het bekomen vermogen van de voeding en het verloren vermogen in de transistor als functie van de tijd. (rechts onder) Stroom versus spanning.

In een aantal toepassingen is zowel de voedingsspanning als de impedantie van de belasting een gegeven. Het kan bijvoorbeeld zijn dat het circuit moet werken op een gegeven batterijspanning en dat de impedantie van de belasting vast ligt, bijvoorbeeld een gegeven antenne of een coax kabel. In dat geval zullen we vertrekken vanuit de gegeven voedingsspanning en Eq.(10) gebruiken om de verwachte impedantie uit te rekenen. Tenslotte passen we dan de verwachte impedantie aan tot de gewenste impedantie aan de hand van een transformator met de juiste wikkelverhouding. We kunnen het vorig ontwerp aan de hand van een transformator met wikkelverhouding 1.83 ook aanpassen aan een coax lijn van 50 Ohm (zie Fig. 81).

Fig. 81 Voorbeeld 1 : Aanpassing 50 Ohm

Voorbeeld 2: 50W versterker bij 137.77 kHz

Dit is een voorbeeld afkomstig van een driver voor amateur korte-golf zender. We wensen een klasse E versterker die een vermogen van 50W moet kunnen leveren bij een frequentie van 137.77 kHz, bij een voedingsspanning van 12.5V, met een Q factor van 5 en een saturatiespanning van de bipolaire transistor van 0.9 V. Wanneer we de vergelijkingen Eq.(10) tot Eq.(13) gebruiken om de elementen van dit circuit uit te rekenen bekomen we de volgende waardes voor de verschillende componenten:

Opgave Voorbeeld 2

• Verwacht vermogen : 50W

• Frequentie : 137.77 kHz

• Voedingsspanning : 12.5 V

• Kwaliteitsfactor : 5

• Saturatiespanning 0.9V

RL = 1.39 Ohm
C₁ = 176.90 nF (i.e. complexe impedantie van -6.53 i Ohm)
C₂ = 222.56 nF (i.e. complexe impedantie van -5.19 i Ohm)
L₂ = 8.03 uH (i.e. complexe impedantie van 6.95 i Ohm)
Totale complexe impedantie (seriekring):  1.76 i Ohm
Maximale stroom uit de voeding: 4310.34 mA
Maximale source-drain spanning (transistor): 55.62 V
Hierbij werd een 80% veiligheidsmarge genomen
We kunnen de uitgang omwerken naar een impedantie van 50 Ohm
door een transformator met wikkelverhouding: 6.00 

Fig. 82 Schema van het tweede voorbeeld met berekende waardes

Fig. 83 Schema van het tweede voorbeeld met berekende waardes en aanpassing aan een 50 Ohm coax

Spice Listing 13 Klasse E spice file

* Class E amp 1
M_M1         2 1 0 0 FDB33N25 
L_L1         2 3  270uH  
C_C1         2 0  176.9nF  
L_L2         4 5  8.03uH  
C_C2         2 4  222.56nF  
R_RL         5 0  1.39 
V_Vdd        3 0 12.5V
V_Vin        1 0 PULSE(0 9 3.65u 20n 20n 3.65u 7.3u) DC=0
.model FDB33N25 VDMOS(Rg=3 Rd=40m Rs=27m Vto=5.35 Kp=35 lambda=.05 Cgdmax=1.1n Cgdmin=25p Cgs=1.7n Cjo=800p Is=7.94p Rb=7m mfg=Fairchild Vds=250 Ron=94m Qg=37n)

Fig. 84 Voorbeeld 2: bekomen oscillatie

Fig. 85 Detail opstartsequentie van het tweede voorbeeld

Fig. 86 1 periode van de Steady State van het tweede voorbeeld

Voorbeeld 3: On-chip 2 GHz Klasse E versterker voor GSM toepassingen

In 1999 hebben King-Chun Tsai en Paul Gray een 1.9GHz klasse E versterker voor GSM en DECT telefoon toepassingen ontworpen [7]. De versterker bestaat uit 2 stages en elke stage is fully-differential uitgewerkt.

In de 2de stage herkenen we 2 gekruiste klasse E versterkers:

• L3 met de ingangscapaciteit van de complementaire transistor M23 die dan de kring L5 en C1 (5.1 pF) aanstuurt. De belasting is een 50 Ohm transmissielijn.

• L4 met de ingangscapaciteit van de complementaire transistor M22 die dan de kring L6 en C1 (5.1 pF) aanstuurt. De belasting is ook een 50 Ohm transmissielijn.

Hiervoor staat dan de eerste stage met ook 2 gekruiste klasse E versterkers:

• L1 met de ingangscapaciteit van de complementaire transistor M13 en de gate-source capaciteit van M21. Er is ook een seriekring als belasting, namelijk de gate-drian capaciteit van M21 in serie met onder andere L3. Deze seriekring is echter niet het beangrijkste. Het belangrijkste effect is spanningszwaai op de gate van M21, wat ook bekomen wordt zonder de seriekring.

• L2 met de ingangscapaciteit van de complementaire transistor M12 en de gate-source capaciteit van M24. Er is ook een seriekring als belasting, namelijk de gate-drian capaciteit van M24 in serie met onder andere L4. Deze seriekring is echter niet het beangrijkste. Het belangrijkste effect is spanningszwaai op de gate van M24, wat ook bekomen wordt zonder de seriekring.

Het uiteindelijke schema zie je in schema 87

Fig. 87 Schema van de klasse E versterker met injection locking.

We kunnen dit schema uitwerken als een spice file (zie Spice Listing 14) en deze spice file simuleren.

Spice Listing 14 Klasse E spice file met injection locking

* Class E Tsai
M_SWn        0 11 10 0 nmos W=31580u L=0.35u
M_SWp        3 11 10 3 pmos W=500u L=0.35u
* stage 1
L_L1         3 6  0.37nH
L_L2         3 7  0.37nH
M_11         10 1 6 0 nmos W=980u L=0.35u
M_12         10 7 6 0 nmos W=980u L=0.35u
M_13         10 6 7 0 nmos W=980u L=0.35u
M_14         10 2 7 0 nmos W=980u L=0.35u
* stage 2
M_21         10 6 8 0 nmos W=3600u L=0.35u
M_22         10 9 8 0 nmos W=4800u L=0.35u
M_23         10 8 9 0 nmos W=4800u L=0.35u
M_24         10 7 9 0 nmos W=3600u L=0.35u
L_L3         3 8  0.37nH
L_L4         3 9  0.37nH
L_L5         8 4  0.8nH 
L_L6         9 5  0.8nH 
C_C1         4 5  5.1pF
* belasting
R_RL1        4 0  50 
R_RL2        5 0  50 
.include simul/berkeley35.lib

Het circuit is uitgevoerd in een 0.35 \(\mu\)m technologie. Normaal kan deze technologie gebruik maken van 5V voedingsspanning. Toch gebruiken we dit circuit met een voedingsspanning tussen de 1V en 2V. Dit is omdat er door de oscillatie hogere gate-spanningen worden bekomen en de maximale spanning over de gate is 5V.

Fig. 88 (boven) aangelegde spanningen, (midden) spanning op de interne knopen en (onder) bekomen spanningen van het schema van Fig. 87.

Fig. 88 toont de eerste 20 periodes uit de simulatie van het circuit. We merken op dat na ongeveer 10 periodes de uitgangssignalen in fase gaan lopen met de ingangssignalen.

Fig. 89 Spanning over (linksboven), stroom door (linksonder) en vermogendissipatie (rechtsboven) van de input transistor van stage 2 (M21) als funktie van de tijd.(rechtsonder) De stroomdoor als functie van de spanning over M21. De gebieden met hoge spanning zonder stroom zijn in het groen aangegeven. De gebieden met hoge stroom en een beperkte spanning zijn in het rood aangegeven.

Fig. 89 gaat dieper in op de input transistor (M21) van stage 2. We herkennen de gebieden zonder stroom en met veel spanning over de transistor (groene achtergrond) en de gebieden met veel stroom en een beperkte spanning over de transistor (rode achtergrond). Toch is er ook een gebied waarin we zowel hoge stromen als hoge spanningen bekomen (witte achtergrond), In dit gebied hebben we dus geen perfecte klasse E werking. De tweede input transistor van stage 2 (M24) gedraagt zich op dezelfde wijze. Fig. 90 toont hetzelfde voor de kruisgekoppelde transistor (M22) van stage 2. Hier kunnen we wel de totale periode opdelen in de 2 gebieden die de Klasse E kenmerken. De tweede kruisgekoppelde transistor van stage 2 (M23) gedraagt zich op dezelfde wijze.

Fig. 90 Spanning over (linksboven), stroom door (linksonder) en vermogendissipatie (rechtsboven) van de koppeltransistor van stage 2 (M22) als funktie van de tijd.(rechtsonder) De stroom door als functie van de spanning over M22. De gebieden met hoge spanning zonder stroom zijn in het groen aangegeven. De gebieden met hoge stroom en een beperkte spanning zijn in het rood aangegeven.

Overzicht van de state-of-the-art

In Tabel 5 tonen we een overzicht van de state-of-the-art voor on chip klasse E versterkers. We merken op dat er vermogens tot 37 W kunnen bekomen worden met de 180 nm nodes. Voor de oudere 500 nm nodes kunnen er vermogens tot 100 W bekomen worden. Dit is vooral omdat er op de oudere technologienodes ook hogere spanningen kunnen gebruikt worden (tot 40V). De frequenties voor deze ontwerpen blijven beperkt tot 6 tot 13.56 MHz.

Tabel 5 Overzicht van de state-of-the-art

	ISSCC’18 [8]	ISSCC’19 [9]	ISSCC’24 [10]	JSSC’24 [11]	ISSCC’25 [12]	ESSERC’25 [x]
Process node	0.5 um	0.5 um	0.18 um	0.18 um	0.18 um	0.18 um
Technologie	CMOS SOI	CMOS SOI	BCD	BCD SOI	SOI	BCD
Type	Klasse E	Differentiele klasse E	Hybride klasse ED	gereguleerde Klasse E	Klasse E	Klasse E
\(V_{in}\) [V]	40	40	7.4	10	20-35	10-20
Frequentie [MHz]	6.78	13.56	6.78	6.78	6.78	6.78
Piek output power [W]	70	100	27	27	33	37.8
Piek Tx efficientie [%]	90	91	N.A.	N.A.	94.2	94
Piek E2E Efficientie [%]	N.A.	N.A.	82	80	74.7	86.3

Samenvatting en Conclusies

Belangrijkste Eigenschappen van Klasse E Versterkers

De klasse E versterker biedt verschillende belangrijke voordelen:

• Efficiëntie:

  • Theoretisch tot 100% efficiëntie mogelijk

  • Praktisch 85-95% haalbaar

  • Ideaal voor batterij-gevoede toepassingen

• Frequentiebereik:

  • Optimaal voor hoogfrequent toepassingen (MHz-GHz)

  • Beperkte bandbreedte rond resonantiefrequentie

  • Geschikt voor narrowband communicatie

• Implementatie:

  • Eenvoudige topologie met één transistor

  • Kritische timing tussen spanning en stroom

  • Nauwkeurige componentwaarden vereist

Toepassingsgebieden

• Moderne Communicatiesystemen:

  • GSM/UMTS/LTE zendversterkers

  • WiFi en Bluetooth transmitters

  • RFID en NFC systemen

  • Satellietcommunicatie

• Vooruitblik:

  • 5G millimeter-golf toepassingen

  • IoT low-power transmitters

  • Draadloze energieoverdracht

  • Geïntegreerde on-chip oplossingen